Option Explicit
'社会保険月額算定届クラス

'プロパティの実体
Private mlngFID As Long         '社員ID
Private mlngMayData As Long     '5月給与
Private mlngJuneData As Long    '6月給与
Private mlngJulyData As Long    '7月給与
Private mlngGoukei As Long      '合計
Private mlngHeikin As Long      '平均

Public Property Get FID() As Long

    FID = mlngFID
    
End Property

Public Property Let FID(ByVal lngFID As Long)

    mlngFID = lngFID
    
End Property

Public Property Get MayData() As Long

    MayData = mlngMayData
    
End Property

Public Property Let MayData(ByVal lngMayData As Long)

    mlngMayData = lngMayData
    
End Property

Public Property Get JuneData() As Long

    JuneData = mlngJuneData
    
End Property

Public Property Let JuneData(ByVal lngJuneData As Long)

    mlngJuneData = lngJuneData
    
End Property

Public Property Get JulyData() As Long

    JulyData = mlngJulyData
    
End Property

Public Property Let JulyData(ByVal lngJulyData As Long)

    mlngJulyData = lngJulyData
    
End Property

'ワークシートへ書き出し
Public Sub LetProperty(ByVal objws As Worksheet, ByVal lngRow As Long)

'引数[objWS]：ワークシート
'引数[lngRow]：レコード

    Dim i As Integer    '整数型カウンタ
    
    Call KingakuSum
    Call KingakuAverage
    
    objws.Cells(lngRow, 1).Value = mlngFID
    objws.Cells(lngRow, 2).Value = Format$(mlngMayData, "#,##0")
    objws.Cells(lngRow, 3).Value = Format$(mlngJuneData, "#,##0")
    objws.Cells(lngRow, 4).Value = Format$(mlngJulyData, "#,##0")
    objws.Cells(lngRow, 5).Value = Format$(mlngGoukei, "#,##0")
    objws.Cells(lngRow, 6).Value = Format$(mlngHeikin, "#,##0")
    
    '網掛けと罫線
    For i = 1 To 6
        With objws.Cells(lngRow, i)
            If i < 6 Then .Borders(xlEdgeRight).LineStyle = xlContinuous
            If lngRow Mod 2 = 0 Then
                With .Interior
                    .ColorIndex = 37
                    .Pattern = xlSolid
                End With
            End If
        End With
    Next
    
End Sub

'合計
Private Sub KingakuSum()

    mlngGoukei = mlngMayData + mlngJuneData + mlngJulyData
    
End Sub

'平均
Private Sub KingakuAverage()

    Const intNum As Integer = 3 '3ヶ月平均
    
    mlngHeikin = CLng(mlngGoukei / intNum)
    
End Sub